Self-Deleting Macros

Patrick is writing a macro, and he wants the macro to delete itself after a specific expiration date is reached. There are a couple of ways that this task can be approached. First, you could write a macro that would only function before a specific date, in the following manner:

Sub MyMacro()

    ExpirationDate = #2/1/2007#
    If Now() < ExpirationDate Then

        'Rest of macro goes here

    End if
End Sub

The idea is that if (in this case) the current date is prior to February 1, 2007, then the main body of the macro will execute. If it is February 1 or later, then the macro will not execute. This approach, of course, does not actually delete the macro; it simply checks to see that the macro is being executed before a certain date.

To actually get rid of the macro code, you need to take a different approach:

Private Sub Workbook_Open()
    Dim VBComp As VBIDE.VBComponent
    Dim VBComps As VBIDE.VBComponents

    'Delete if Past Date
    If Date >= #2/1/2007# Then
        Set VBComps = ActiveWorkbook.VBProject.VBComponents

        For Each VBComp In VBComps
            Select Case VBComp.Type
                Case vbext_ct_StdModule, vbext_ct_MSForm, _
                  vbext_ct_ClassModule
                    VBComps.Remove VBComp
                Case Else
                    With VBComp.CodeModule
                        .DeleteLines 1, .CountOfLines
                    End With
            End Select
        Next VBComp
    End If

    Set VBComps = Nothing
    Set VBComp = Nothing
End Sub

This code was adapted from a macro originally written by Chip Pearson, available on his site at the following address:

http://www.cpearson.com/excel/vbe.htm

To make the macro work, you'll need to make sure that there is a reference to Microsoft Visual Basic for Applications Extensibility. (You do this by choosing, in the VB Editor, Tools | References and then choosing Microsoft Visual Basic for Applications Extensibility in the available references.)

The macro runs when the workbook is opened, and if the date is greater than or equal to Feburary 1, 2007, then the each component of the VBProject is deleted. This means that the macro is very powerful, because it deletes everything, not just a single procedure or module.

There are a couple of things to keep in mind with this macro, of course. First, if the user chooses to not enable macros when the workbook is opened, then this code will never run and the macro won't be deleted. Second, deleting macros in this way obviously introduces changes to the workbook. That means that when the workbook is closed, the user will be asked if they want to save their changes. If they choose not to, then the deletions will not be saved and the macro will again run the next time the workbook is opened.