Setting Print Ranges for Multiple Worksheets

Martin asked if there is a way to set print ranges for multiple worksheets at the same time. He has a workbook containing a number of worksheets structured exactly the same, and he wants their respective print ranges to be exactly the same.

As Martin has discovered, there is no way to do this directly in Excel. When you select multiple worksheets, select the area you want set as the print area, and then try to set the print area, you quickly discover that the option to do the setting is grayed out, so you cannot select that option.

There are several things you can try, however. One is to start with a new workbook and develop a single worksheet that contains the print area as you would want it on all worksheets. Then, copy the worksheet however many times desired in the workbook. The copied worksheets will have the print area set as it was in the first worksheet.

The other option is to create a macro that will do the print-area setting for you. Consider the following macro, which will set the print area for all the selected worksheets to whatever the print area is on the active worksheet. (When more than one worksheet is selected, the active worksheet is the one that is visible when you run the macro.)

Sub SetPrintAreas1()
    Dim sPrintArea As String
    Dim wks As Worksheet

    sPrintArea = ActiveSheet.PageSetup.PrintArea
    For Each wks In ActiveWindow.SelectedSheets
        wks.PageSetup.PrintArea = sPrintArea
    Next
    Set wks = Nothing
End Sub

If you prefer to have the print area set to some range that you specify, rather than needing to set the print area on the active worksheet first, then you can make one small change to the macro so that it uses a range for the print area:

Sub SetPrintAreas2()
    Dim sPrintArea As String
    Dim wks As Worksheet

    sPrintArea = "A7:E22"
    For Each wks In ActiveWindow.SelectedSheets
        wks.PageSetup.PrintArea = sPrintArea
    Next
    Set wks = Nothing
End Sub

To choose a different print area for your needs, replace the range that is assigned to the sPrintArea variable. If you figure that you may use the macro quite a bit, in a number of different workbooks, or if you figure that you may need to change the print area regularly, you could change the macro so that it prompts the user for a range to use:

Sub SetPrintAreas3()
    Dim sPrintArea As String
    Dim wks As Worksheet

    sPrintArea = InputBox("Enter print area range")
    For Each wks In ActiveWindow.SelectedSheets
        wks.PageSetup.PrintArea = sPrintArea
    Next
    Set wks = Nothing
End Sub