Resizing a Text Box in a Macro

Rob has a text box, in a worksheet, that contains text copied from Word. He wants to know how he can resize the text box using a macro, so that it covers a specific range of cells.

There are a couple of ways you can approach this task. One is to specify, in the macro, exactly which cells you want to cover with the text box, and then adjust the properties of the text box to match the characteristics of the cells you specify.

Sub ResizeBox1()
    Dim sTL As String
    Dim sBR As String
    Dim rng As Range

    ' Change top-left and bottom-right addresses as desired
    sTL = "A1"
    sBR = "M40"

    ' Ensure a text box is selected
    If TypeName(Selection) <> "TextBox" Then
        MsgBox "Text box not selected"
        Exit Sub
    End If

    With Selection
        Set rng = ActiveSheet.Range(sTL)
        .Top = rng.Top
        .Left = rng.Left
        Set rng = ActiveSheet.Range(sBR)
        .Width = rng.Left + rng.Width
        .Height = rng.Top + rng.Height
    End With
    Set rng = Nothing
End Sub

In order to use the macro, change the address of the cells you want to use for the top-left and bottom-right of the text box. Then, select the text box and run the macro.

If you prefer, you could use a named range to specify the range to be covered by the text box. The following macro expects that the range will be named RangeToCover. When you select the text box and run the macro, the text box is resized to match the size of the range.

Sub ResizeBox2()
    Dim l_rRangeToCover As Range
    Dim l_rLowerRight As Range

    ' Ensure a text box is selected
    If TypeName(Selection) <> "TextBox" Then
        MsgBox "Text box not selected"
        Exit Sub
    End If

    ' Get the range to cover
    Set l_rRangeToCover = _
      ActiveSheet.Range(Names("RangeToCover").RefersToRange.Value)

    ' Get its lower right cell
    Set l_rLowerRight = _
      l_rRangeToCover.Cells( _
      l_rRangeToCover.Rows.Count, _
      l_rRangeToCover.Columns.Count)

    ' Resize the text box
    With Selection
        .Left = l_rRangeToCover.Left
        .Top = l_rRangeToCover.Top
        .Width = l_rLowerRight.Left + l_rLowerRight.Width - .Left
        .Height = l_rLowerRight.Top + l_rLowerRight.Height - .Top
    End With
End Sub