Sorting by Colors

Excel allows you to sort the data in your worksheets by any number of attributes. One of the things that you cannot intrinsically sort by, however, is the color of cells. For some applications this could be a very handy feature. The following macro, SortByColor, will sort a table based on the color with which a cell is formatted.

Sub SortByColor()
    On Error GoTo SortByColor_Err

    Dim sRangeAddress As String
    Dim sStartCell As String
    Dim sEndCell As String
    Dim rngSort As Range
    Dim rng As Range

    Application.ScreenUpdating = False

    sStartCell = InputBox("Enter the cell address of the " & _
      "top cell in the range to be sorted by color" & _
      Chr(13) & "i.e.  'A1'", "Enter Cell Address")

    If sStartCell > "" Then
        sEndCell = Range(sStartCell).End(xlDown).Address
        Range(sStartCell).EntireColumn.Insert
        Set rngSort = Range(sStartCell, sEndCell)
        For Each rng In rngSort
            rng.Value = rng.Offset(0, 1).Interior.ColorIndex
        Next
        Range(sStartCell).Sort Key1:=Range(sStartCell), _
          Order1:=xlAscending, Header:=xlNo, _
          Orientation:=xlTopToBottom
        Range(sStartCell).EntireColumn.Delete
    End If

SortByColor_Exit:
    Application.ScreenUpdating = True
    Set rngSort = Nothing
    Exit Sub

SortByColor_Err:
    MsgBox Err.Number & ": " & Err.Description, _
      vbOKOnly, "SortByColor"
    Resume SortByColor_Exit
End Sub

The macro works by first asking you the beginning cell of the range you want to sort. This should be the top-most cell in the range. The macro then inserts a column (just temporarily) in which color values can be stored. It then steps through each cell in the range defined by the starting cell you specified.

SortByColor assumes your data table doesn't have a header row. If it does, you should change the actual sorting command. Simply change Header:=xlNo to Header:=xlYes.

You should note that the SortByColor macro will only sort cells based on the explicit color applied to the cell, it will not sort if the color of the cell is the result of conditional formatting.